c-----------------------------------------------------------------------
c
c  Name:
c      FUNCTION CENWAV 
c
c  Purpose:
c      Compute an effective central wavenumber from an array of
c      spectral response values.
c
c  Usage:
c      RESULT = CENWAV( N, W1, W2, SRF )
c 
c  Input:
c      N       Number of points in spectral response array
c      W1      Lower wavenumber limit of spectral response array
c              (inverse centimeters)
c      W2      Upper wavenumber limit of spectral response array
c              (inverse centimeters)
c      SRF     Spectral response data, typically at 0.1 inverse
c              centimeter resolution (normalized to 1.0 or
c              un-normalized are both acceptable).
c
c  Output:
c      CENWAV  Effective central wavenumber (inverse centimeters)
c
c  Revised:
c      Liam.Gumley@ssec.wisc.edu
c      $Id: cenwav.f,v 1.1 1999/11/22 22:49:02 gumley Exp $
c
c-----------------------------------------------------------------------

      real function cenwav( n, w1, w2, srf )

      implicit none
      
c ... arguments

      integer n
      real w1, w2, srf( * )

c ... local variables

      double precision sumw, sumr
      real w
      integer i
      
c ... compute central wavenumber

      sumw = 0.0d0
      sumr = 0.0d0
      
      do i = 1, n
        w = ( w2 - w1 ) * real( i - 1 ) / real( n - 1 ) + w1
        sumw = sumw + dble( srf( i ) ) * dble( w )
        sumr = sumr + dble( srf( i ) )
      enddo

      cenwav = sngl( sumw / sumr ) 
      
      end