FUNCTION NEWFILE, ROOT, EXTENSION = EXTENSION

rcs_id = "$Id: newfile.pro,v 1.1 1999/11/15 21:09:51 gumley Exp $"

;+
;Purpose:
;   Return an unused filename of the form "root???.extension", where ???
;   is an integer in the range 001-999.
;
;Usage:
;   NAME = NEWFILE( ROOT )
;
;Input:
;   ROOT       String variable specifying the root of the filename.
;
;Optional keywords:
;   EXTENSION  String variable specifying the extension of the filename.
;
;Revised:
;   23-JUN-1997 Liam Gumley, CIMSS/SSEC
;
;Example:
; NAME = NEWFILE( "output" )
; PRINT, NAME
; NAME = NEWFILE( "test", EXTENSION = "gif" )
; PRINT, NAME
;
;-

if n_elements( root ) eq 0 then $
  message, 'Input parameter ROOT was missing'
  
for version = 1, 999 do begin
  if n_elements( extension ) eq 0 then begin
    name = string( root( 0 ), version, format = '( a, i3.3 )' )
  endif else begin
    name = string( root( 0 ), version, extension( 0 ), format = '( a, i3.3, ".", a )' )
  endelse
  name = strcompress( name, /remove_all )
  openr, lun, name, /get_lun, error = status
  if status ne 0 then return, name
  free_lun, lun
endfor

message, 'All filenames of the form ' + name + ' are in use'

END