FUNCTION GET_SDS_NAME, BAND, DATA_TYPE

;- Get the SDS name for a MODIS band within a L1B HDF file

COMPILE_OPT IDL2

;- Check arguments
if (n_elements(band) eq 0) then message, 'Argument BAND is undefined'
if (n_elements(data_type) eq 0) then message, 'Argument DATA_TYPE is undefined'

;- Get 1KM SDS name
if (data_type eq '1KM') then begin
  case 1 of
    (band ge  1 and band le  2) : sds_name = 'EV_250_Aggr1km_RefSB'
    (band ge  3 and band le  7) : sds_name = 'EV_500_Aggr1km_RefSB'
    (band ge  8 and band le 19) : sds_name = 'EV_1KM_RefSB'
    (band eq 26)                : sds_name = 'EV_1KM_RefSB'
    (band ge 20 and band le 36) : sds_name = 'EV_1KM_Emissive'
    else : message, 'Invalid band number'
  endcase
endif

;- Get HKM SDS name
if (data_type eq 'HKM') then begin
  case 1 of
    (band ge  1 and band le  2) : sds_name = 'EV_250_Aggr500_RefSB'
    (band ge  3 and band le  7) : sds_name = 'EV_500_RefSB'
    else : message, 'Invalid band number'
  endcase
endif

;- Get QKM SDS name
if (data_type eq 'QKM') then begin
  case 1 of
    (band ge  1 and band le  2) : sds_name = 'EV_250_RefSB'
    else : message, 'Invalid band number'
  endcase
endif

;- Return SDS name
return, sds_name

END