FUNCTION CERES_PLANCK, BRT, UNITS

;+
; DESCRIPTION:
;    Compute Planck radiance for the CERES window band.
;
; USAGE:
;    RESULT = CERES_BRIGHT(BRT, UNITS)
;
; INPUT PARAMETERS:
;    BRT           Brightness temperature (Kelvin)
;    UNITS         Flag defining output radiance units
;                  0 => milliWatts per square meter per steradian per
;                       inverse centimeter
;                  1 => Watts per square meter per steradian per micron
;
; OUTPUT PARAMETERS:
;    CERES_PLANCK  Planck radiance (units are determined by UNITS)
;-

;- Effective central wavenumber (inverse centimenters)
cwn = 1.042175E+03

;- Temperature correction slope (no units)
tcs = 9.789205E-01

;- Temperature correction intercept (Kelvin)
tci = 6.724265E+00

;- Compute Planck radiance
if (units eq 1) then begin

  ;- Radiance units are Watts per square meter per steradian per micron
  rad = planck_m(1.0e+4 / cwn, brt * tcs + tci)

endif else begin

  ;-  Radiance units are milliWatts per square meter per steradian per wavenumber
  rad = planc_m(cwn, brt * tcs + tci)

endelse

;- Return result to caller
return, rad

END