FUNCTION CERES_BRIGHT, RAD, UNITS

;+
; DESCRIPTION:
;    Compute brightness temperature for the CERES window band.
;
; USAGE:
;    RESULT = CERES_BRIGHT(RAD, UNITS)
;
; INPUT PARAMETERS:
;    RAD           Planck radiance (units are determined by UNITS)
;    UNITS         Flag defining input radiance units
;                  0 => milliWatts per square meter per steradian per
;                       inverse centimeter
;                  1 => Watts per square meter per steradian per micron
;
; OUTPUT PARAMETERS:
;    CERES_BRIGHT  Brightness temperature (Kelvin)
;-

;- Effective central wavenumber (inverse centimenters)
cwn = 1.042175E+03

;- Temperature correction slope (no units)
tcs = 9.789205E-01

;- Temperature correction intercept (Kelvin)
tci = 6.724265E+00

;- Compute brightness temperature
if (units eq 1) then begin

  ;- Radiance units are Watts per square meter per steradian per micron
  brt = (bright_m(1.0e+4 / cwn, rad) - tci) / tcs

endif else begin

  ;- Radiance units are milliWatts per square meter per steradian per wavenumber
  brt = (brite_m(cwn, rad) - tci) / tcs

endelse

;- Return result to caller
return, brt

END