c-----------------------------------------------------------------------
c
c  Name:
c      FUNCTION WPLANC
c
c  Purpose:
c      Compute monochromatic Planck radiance in milliWatts per square
c      meter per steradian per wavenumber given brightness temperature
c      in.
c
c  Usage:
c      RESULT = WBRITE( WN, TEM )
c 
c  Input:
c      WN      Wavenumber (inverse centimeters)
c      TEM     Brightness temperature (Kelvin)
c
c  Output:
c      RESULT  Planck radiance (milliWatts per square meter per
c              steradian per wavenumber)
c
c  Revised:
c      Liam.Gumley@ssec.wisc.edu
c      $Id: wplanc.f,v 1.3 1999/11/11 20:04:47 gumley Exp $
c
c-----------------------------------------------------------------------

      real function wplanc( wn, tem )

      implicit none
      
c ... arguments

      real wn, tem
      
c ... local variables
            
      double precision h, c, b, c1, c2

c ... Planck function constants
      
      parameter( h = 6.6260755d-27, c = 2.9979246d+10,
     &  b = 1.380658d-16, c1 = 2.0d0 * h * c**2, c2 = h * c / b )

      wplanc = sngl( c1 * dble( wn )**3 /
     &  ( exp( c2 * dble( wn ) / dble( tem ) ) - 1.0d0 ) )

      end