c-----------------------------------------------------------------------
c
c  Name:
c      FUNCTION WBRITE
c
c  Purpose:
c      Compute brightness temperature in Kelvin given monochromatic
c      Planck radiance in milliWatts per square meter per steradian per
c      wavenumber.
c
c  Usage:
c      RESULT = WBRITE( WN, RAD )
c 
c  Input:
c      WN      Wavenumber (inverse centimeters)
c      RAD     Planck radiance (milliWatts per square meter per
c              steradian per wavenumber)
c
c  Output:
c      RESULT  Brightness temperature (Kelvin)
c
c  Revised:
c      Liam.Gumley@ssec.wisc.edu
c      $Id: wbrite.f,v 1.3 1999/11/11 20:04:46 gumley Exp $
c
c-----------------------------------------------------------------------

      real function wbrite( wn, rad )

      implicit none

c ... arguments

      real wn, rad

c ... local variables
      
      double precision h, c, b, c1, c2

c ... Planck function constants
      
      parameter( h = 6.6260755d-27, c = 2.9979246d+10,
     &  b = 1.380658d-16, c1 = 2.0d0 * h * c**2, c2 = h * c / b )

      wbrite = sngl( c2 * dble( wn ) /
     &  log( c1 * dble( wn )**3 / dble( rad ) + 1.0d0 ) )
      
      end