c-----------------------------------------------------------------------
c
c  Name:
c      FUNCTION PLANCK
c
c  Purpose:
c      Compute monochromatic Planck radiance in Watts per square meter
c      per steradian per micron given brightness temperature in Kelvin.
c
c  Usage:
c      RESULT = PLANCK( WV, TEM )
c 
c  Input:
c      WV      Wavelength (microns)
c      TEM     Brightness temperature (Kelvin)
c
c  Output:
c      RESULT  Planck radiance (Watts per square meter per
c              steradian per micron)
c
c  Revised:
c      Liam.Gumley@ssec.wisc.edu
c      $Id: planck.f,v 1.3 1999/11/11 20:04:46 gumley Exp $
c
c-----------------------------------------------------------------------

      real function planck( wv, tem )

      implicit none

c ... arguments

      real wv, tem

c ... local variables
      
      double precision h, c, b, c1, c2, ws

c ... Planck function constants
      
      parameter( h = 6.6260755d-34, c = 2.9979246d+8,
     &  b = 1.380658d-23, c1 = 2.0d0 * h * c**2, c2 = h * c / b )

c ... scale wavelength from microns to meters

      ws = 1.0d-6 * dble( wv )

c ... compute radiance

      planck = sngl( 1.0d-6 * c1 /
     &  ( ws**5 * ( exp( c2 / ( ws * dble( tem ) ) ) - 1.0d+0 ) ) )

      end