c-----------------------------------------------------------------------
c
c  Name:
c      FUNCTION BRIGHT
c
c  Purpose:
c      Compute brightness temperature in Kelvin given monochromatic
c      Planck radiance in Watts per square meter per steradian per
c      micron.
c
c  Usage:
c      RESULT = BRIGHT( WV, RAD )
c 
c  Input:
c      WV      Wavelength (microns)
c      RAD     Planck radiance (Watts per square meter per
c              steradian per micron)
c
c  Output:
c      RESULT  Brightness temperature (Kelvin)
c
c  Revised:
c      Liam.Gumley@ssec.wisc.edu
c      $Id: bright.f,v 1.3 1999/11/11 20:04:43 gumley Exp $
c
c-----------------------------------------------------------------------

      real function bright( wv, rad )

      implicit none

c ... arguments

      real wv, rad

c ... local variables
      
      double precision h, c, b, c1, c2, ws

c ... Planck function constants
      
      parameter( h = 6.6260755d-34, c = 2.9979246d+8,
     &  b = 1.380658d-23, c1 = 2.0d0 * h * c**2, c2 = h * c / b )

c ... scale wavelength from microns to meters

      ws = 1.0d-6 * dble( wv )

c ... compute brightness temperature

      bright = sngl( c2 /
     &  ( ws * log( c1 / ( 1.0d6 * dble( rad ) * ws**5 ) + 1.0d0 ) ) )

      end